Der eingegeben bzw. aktivierte Produktschlüssel "Product Key" (auch "CD-Schlüssel" genannt) wird in der Regel an keiner Stelle im System für den Benutzer angezeigt. Unter "System" in der Systemsteuerung wird nur die Produkt-ID-Nummer sowie die Windowsversion eingeblendet. In der Registrierung von Windows wird der Schlüssel codiert gespeichert. Mit Hilfe eines kleinen Skripts kann der Produktschlüssel ausgelesen und decodiert werden, ohne dass die Verwendung zusätzlicher Software erforderlich ist.

So geht's:

• Öffnen Sie einen Texteditor (z.B.: "Notepad.exe").
• Kopieren Sie das unten stehende VBScript in den Editor.
• Speichern Sie die Datei unter einem beliebigen Namen mit der Dateiendung ".vbs" ab. Z.B.: "ProductKey.vbs"
• Öffnen Sie den Windows-Explorer (bzw. "Arbeitsplatz" / "Computer")
• Mit einem Doppelklick kann das Skript nun ausgeführt werden.
• Es wird die aktuelle Windowsversion und der Produktschlüssel angezeigt.

VisualBasicScript (VBS):

' Ausgabe des Produktschlüssels ("Product Key")
' Systemanforderungen: Windows 2000 oder höher
' (c) Windowspage 2011. Alle Rechte vorbehalten.

DIM objFS, objShell
DIM strName, strKey

SET objShell = CreateObject("WScript.Shell")

strName = objShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProductName")
IF Len(strName) > 0 THEN
   strKey = DecodeKey("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId")
   MsgBox "Produkt: " & vbTab & vbTab & strName & vbCrLf & "Produktschlüssel: " & vbTab & strKey, vbOKOnly or vbInformation, "Produktname und -schlüssel"
END IF

Function DecodeKey(RegKey)
   BinKey = objShell.RegRead(RegKey)
   CONST KeyOffset = 52
   iLen = 28
   szChars = "BCDFGHJKMPQRTVWXY2346789"
   DO
     x = 0
     n = 14
     DO
       x = x * 256
       x = BinKey(n + KeyOffset) + x
       BinKey(n + KeyOffset) = (x \ 24) and 255
       x = x Mod 24
       n = n - 1
     LOOP WHILE n >= 0
     iLen = iLen - 1
     szProductKey = mid(szChars, x + 1 ,1 ) & szProductKey
     if (((29 - iLen) Mod 6) = 0) and (iLen <> -1) then
       iLen = iLen - 1
       szProductKey = "-" & szProductKey
     END IF
   LOOP WHILE iLen >= 0
   DecodeKey = szProductKey
END Function